Chapter 7, Section 7.6

Exercise Therapy Trial

Unstructured Covariance (REML Estimation)

data exercise;
infile 'exercise.dat';
     input id group y0 y2 y4 y6 y8 y10 y12;
     y=y0; day=0; output;
     y=y4; day=4; output;
     y=y6; day=6; output;
     y=y8; day=8; output;
     y=y12; day=12; output;
     drop y0 y2 y4 y6 y8 y10 y12;

data exercise;
     set exercise;

***************************************************;

*   Create additional copy of time variable   *;

***************************************************;

time=day;

title1 Unstructured covariance for strength data;
title2 Exercise Therapy Trial;

proc mixed method=reml noclprint=10; 
     class id group time;
     model y = group time group*time / s chisq;
     repeated time / type=un subject=id r rcorr;

run;

<Selected Output>

Autoregressive Covariance (REML Estimation)

title1 Autoregressive covariance for strength data;
title2 Exercise Therapy Trial;

proc mixed noclprint=10; 
     class id group time;
     model y = group time group*time / s chisq;
     repeated time / type=ar(1) subject=id r rcorr;

run;

<Selected Output>

Exponential Covariance (REML Estimation)

title1 Exponential covariance for strength data;
title2 Exercise Therapy Trial;

proc mixed noclprint=10; 
     class id group time;
     model y = group time group*time / s chisq;
     repeated time / type=sp(exp)(day) subject=id r rcorr;

run;

<Selected Output>