Chapter 5, Section 5.7

Analysis of Response Profiles assuming Equal Mean Response at Baseline

data tlc;

infile 'tlc.dat';

input id group $ lead0 lead1 lead4 lead6;

y=lead0; time=0; output;

y=lead1; time=1; output;

y=lead4; time=4; output;

y=lead6; time=6; output;

drop lead0 lead1 lead4 lead6;

data tlc;
set tlc;

********************************************************;

* Create dummy variables for group and time *;

********************************************************;

succimer=(group='A');

array t(4) t0 t1 t4 t6;
j=0;
do i = 0,1,4,6;
j+1;
t(j)=(time=i);
end;

drop i j;

title1 Analysis of Response Profiles assuming Equal Mean Blood Lead Levels at Baseline;
title2 in the Succimer and Placebo Groups;
title3 Treatment of Lead Exposed Children (TLC) Trial;

proc mixed noclprint=10 order=data;
class id time;
model y = t1 t4 t6 succimer*t1 succimer*t4 succimer*t6 / s chisq;
repeated time / type=un subject=id r;
contrast '3 DF Test of Interaction'
succimer*t1 1, succimer*t4 1, succimer*t6 1 / chisq;

run;

<Selected Output>

Analysis of Response Profiles of Changes in Response from Baseline

data tlc;

infile 'tlc.dat';

input id group $ lead0 lead1 lead4 lead6;

y=lead1; time=1; baseline=lead0; output;

y=lead4; time=4; baseline=lead0; output;

y=lead6; time=6; baseline=lead0; output;

drop lead0 lead1 lead4 lead6;

data tlc;
set tlc;

change=y - baseline;

********************************************************;

* Create dummy variables for group and time *;

********************************************************;

succimer=(group='A');

array t(3) t1 t4 t6;
j=0;
do i = 1,4,6;
j+1;
t(j)=(time=i);
end;

drop i j;

title1 Analysis of Response Profiles of Changes from Baseline;
title2 Treatment of Lead Exposed Children (TLC) Trial;

proc mixed noclprint=10 order=data;
class id time;
model change = succimer t4 t6 succimer*t4 succimer*t6 / s chisq;
repeated time / type=un subject=id r;
contrast '3 DF Test of Main Effect and Interaction'
succimer 1, succimer*t4 1, succimer*t6 1 / chisq;

run;

<Selected Output>

Analysis of Response Profiles of Adjusted Changes in Response from Baseline

data tlc;

infile 'tlc.dat';

input id group $ lead0 lead1 lead4 lead6;

y=lead1; time=1; baseline=lead0; output;

y=lead4; time=4; baseline=lead0; output;

y=lead6; time=6; baseline=lead0; output;

drop lead0 lead1 lead4 lead6;

data tlc;
set tlc;

change=y - baseline;

cbaseline=baseline - 26.406;

********************************************************;

* Create dummy variables for group and time *;

********************************************************;

succimer=(group='A');

array t(3) t1 t4 t6;
j=0;
do i = 1,4,6;
j+1;
t(j)=(time=i);
end;

drop i j;

title1 Analysis of Response Profiles of Adjusted Changes from Baseline;
title2 Treatment of Lead Exposed Children (TLC) Trial;

proc mixed noclprint=10 order=data;
class id time;
model change = cbaseline succimer t4 t6 succimer*t4 succimer*t6 / s chisq;
repeated time / type=un subject=id r;
contrast '3 DF Test of Main Effect and Interaction'
succimer 1, succimer*t4 1, succimer*t6 1 / chisq;

run;

<Selected Output>